From 68b9d1b3dda213143c6a944fe8a97141ee31ba59 Mon Sep 17 00:00:00 2001
From: Giuseppe Corbelli <corbelligiuseppe@mesdan.it>
Date: Wed, 24 Jan 2018 08:57:57 +0100
Subject: [PATCH] Added a fmt.pro to support build using qmake

---
 fmt.pro | 31 +++++++++++++++++++++++++++++++
 1 file changed, 31 insertions(+)
 create mode 100644 fmt.pro

diff --git a/fmt.pro b/fmt.pro
new file mode 100644
index 00000000..293381e6
--- /dev/null
+++ b/fmt.pro
@@ -0,0 +1,31 @@
+# Staticlib configuration for qmake builds
+# For some reason qmake 3.1 fails to identify source dependencies and excludes format.cc and printf.cc
+# from compilation so it _MUST_ be called as qmake -nodepend
+# A workaround is implemented below: a custom compiler is defined which does not track dependencies
+
+TEMPLATE = lib
+
+TARGET = fmt
+
+QMAKE_EXT_CPP = .cc
+
+OBJECTS_DIR = .
+
+CONFIG = staticlib warn_on c++11
+
+FMT_SOURCES = \
+    fmt/format.cc \
+    fmt/ostream.cc \
+    fmt/posix.cc \
+    fmt/printf.cc
+
+fmt.name = libfmt
+fmt.input = FMT_SOURCES
+fmt.output = ${QMAKE_FILE_BASE}$$QMAKE_EXT_OBJ
+fmt.clean = ${QMAKE_FILE_BASE}$$QMAKE_EXT_OBJ
+fmt.depends = ${QMAKE_FILE_IN}
+# QMAKE_RUN_CXX will not be expanded
+fmt.commands = $$QMAKE_CXX -c $$QMAKE_CXXFLAGS $$QMAKE_CXXFLAGS_WARN_ON $$QMAKE_CXXFLAGS_RELEASE_WITH_DEBUGINFO $$QMAKE_CXXFLAGS_CXX11 ${QMAKE_FILE_IN}
+fmt.variable_out = OBJECTS
+fmt.CONFIG = no_dependencies no_link
+QMAKE_EXTRA_COMPILERS += fmt